The Drake Equation

Manipulate[
draken=rstar fp ne fl fi fc l;
SeedRandom[1234];
pts=RandomReal[{-1,1},{10000,3}];
rng=Range[10000];
pick=Union[RandomChoice[rng,Round[draken*10^-3]]];
Graphics3D[{{Lighter[RGBColor[1,.47,0],0.7],Point[pts[[Complement[rng,pick]]]]},{ColorData["HTML","SlateBlue"],Point[pts[[pick]]]}},PlotLabel->Row[{Style["N",Italic]," = ",
draken}],ImageSize->{500,300},PlotRange->1,SphericalRegion->True,ViewAngle->π/6],
{{rstar,10,Row[{"average rate of stars formed per year ",Superscript["R","*"]}]},0,10,1,Appearance->"Labeled"},
{{fp,1,Row[{"fraction of those stars with planets ",Subscript["f","p"]}]},0,1,.01,Appearance->"Labeled"},
{{ne,10,Row[{"average number of planets that can support life per star ",Subscript["n","e"]}]},0,10,1,Appearance->"Labeled"},
{{fl,1,Row[{"fraction of those planets that will develop life ",Subscript["f","l"]}]},0,1,.01,Appearance->"Labeled"},
{{fi,1,Row[{"fraction of those that will be intelligent life ",Subscript["f","i"]}]},0,1,.01,Appearance->"Labeled"},
{{fc,1,Row[{"fraction of those that are able to communicate ",Subscript["f","c"]}]},0,1,.01,Appearance->"Labeled"},
{{l,20000,"number of years they will release signals into space L"},0,20000,1,Appearance->"Labeled"},TrackedSymbols->Manipulate,AutorunSequencing->{4,5,6,7}]

In 1960, Dr. Frank Drake provided a famous equation that can be used to estimate the number of extraterrestrial civilizations that might be able to communicate with people on Earth.

N=(SuperStar[R])×(Subscript[f, p])×(Subscript[n, e])×(Subscript[f, l])×(Subscript[f, i])×(Subscript[f, c])×L

The graphic is an extremely rough representation, due to the huge number of stars and the tiny proportion of stars with civilizations that might be able to communicate with us (amplified by several orders of magnitude in the graphic and colored blue).

Contributed by: Jeff Bryant